[Poradnik] [T�umaczenie] Podstawy tworzenia NPC w WeiDU

Start

Seungri — strony, Obrazki i wiele więcej na WordPress

Oryginalny tekst

Spis tre�ci

Na pocz�tek spis wszystkiego, czego potrzeba by wprowadzi� twego NPCa do gry.
1. Stworzenie plik�w dialogowych (.dlg) dla twojego NPCa
2. Stworzenie pliku postaci (.cre) twojego obecnego NPCa, wraz z parametrami i ekwipunkiem.
3. (opcjonalne) Stworzenie skryptu (.bcs) dla twojej postaci.
4. Stworzenie kodu instalacji WeiDU (.tp2) by mo�na by�o zainstalowa� twojego NPCa na innych komputerach.

1. Pliki .D i .DLG.
Pierwsz� rzecz� do zrobienia jest stworzenie pliku .dlg dla twojej postaci. To sprawi, �e b�dzie ona mog�a porozmawia� z postaci� gracza i przy��czy� si� do dru�yny. Na pocz�tek, stw�rz czysty plik .d poprzez utworzenie zwyk�ego pliku tekstowego oraz przemianowanie go. Nazw� sw�j plik J#Vondo.d. Pierwsz� linijk� kodu jak� powinni�my wpisa� jest "Begin J#Vondo"*, co oznacza, �e podczas kompilowania powstanie plik zwany "J#Vondo.dlg".

* Pami�taj, �e nie musisz u�ywa� prefiksu "J#", to tylko moje nazewnictwo. Wprowadzam to dla wszystkich moich plik�w by ustrzec je przed zapisaniem na plikach innych ludzi. Tw�j prefiks mo�e brzmie� TJ, 01 albo y6 lub cokolwiek innego w tym stylu.
Tak wi�c kod powinien wygl�da� tak:

BEGIN J#Vondo

Podstawowy dialog powinien mie� dwa stany. Pierwszy to ten, w kt�rym gracz i NPC spotykaj� si� po raz pierwszy, drugi za� to ten, kiedy gracz ju� raz odm�wi� wst�pnej propozycji przy��czenia i powr�ci�. Tutaj podaj� jak napisa� pierwszy stan...

IF ~NumTimesTalkedTo(0)~ FirstMeeting // Jest to znacznik pierwszego stanu. Je�eli ~Vondo jeszcze nie rozmawia�~ to rozpoczyna si� blok zwany "FirstMeeting". //
SAY ~Witaj przyjacielu! Na imi� mi Vondo Sprawiedliwy.~ //To jest kwestia Vonda. Nast�pny blok to mo�liwe odpowiedzi dla jego kwestii. //
IF ~GlobalLT("Chapter","GLOBAL",3)~ THEN REPLY ~Hej Vondo, nie widzia�e� gdzie� tutaj czasem Irenicusa?~ GOTO InquireIrenicus
IF ~~ THEN REPLY ~Heja.~ GOTO Greet
+ ~Class(Player1,PALADIN)~ + ~Kiedy widz� paladyna, bez problemu go rozpoznaj�!~ + BothPaladins
++ ~Odejd�.~ + GoAway //To s� wszystkie mo�liwe opcje, jakie gracz mo�e wybra�. Pierwsza jest dost�pna tylko wtedy, gdy gracz jest w rozdziale 1 lub 2. Opcja 2 i 4 s� zawsze dost�pne (IF ~~) za� opcja trzecia jest dost�pna kiedy gracz jest Paladynem. //
END //To ko�czy konkretny blok dialogowy. //

Zauwa� jak r�ni� si� kolejne znaki. Pierwsze dwie kwestie u�ywaj� starych form, za� dwa kolejne korzystaj� z skr�towego formatu. Pierwszy + oznacza "IF". Drugi "+" oznacza "THEN REPLY". Trzeci "+" to "GOTO". Takie rozwi�zanie oszcz�dza wiele czasu.

Tak wi�c nasz plik .d powinien obecnie wygl�da� tak:

BEGIN J#Vondo
IF ~NumTimesTalkedTo(0)~ FirstMeeting
SAY ~Witaj dobry ! Na imi� mi Vondo Sprawiedliwy.~
IF ~GlobalLT("Chapter","GLOBAL",3)~ THEN REPLY ~Hej Vondo, nie widzia�e� gdzie� tutaj czasem Irenicusa?~ GOTO InquireIrenicus
IF ~~ THEN REPLY ~Heja.~ GOTO Greet
+ ~Class(Player1,PALADIN)~ + ~Kiedy widz� paladyna, bez problemu go rozpoznaj�!~ + BothPaladins
++ ~Odejd�.~ + GoAway
END

Tak wi�c obecnie musimy stworzy� nowe stany dla kt�rych stworzyli�my wcze�niej ��cza.

IF ~~ THEN BEGIN InquireIrenicus // To jest kwestia w kt�rej gracz wybra� spytanie si� o Irenicusa. //
SAY ~Nie, jednak mog� ci pom�c w poszukiwaniu go. Jestem paladynem!~ // Odpowied� Vonda //
++ ~Jasne. Do��cz do dru�yny.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT // To ustawi zmienn� dla Vonda, kt�ra b�dzie informowa�a (przydatne jako warunek dla banter�w itp.), i� jest on w dru�ynie. Za� akcja JoinParty() po prostu sprawia, �e przy��cza si� do dru�yny. EXIT ko�czy dialog. //
IF ~~ THEN REPLY ~Nie, odejd�.~ EXIT // To ko�czy dialog, lecz Vondo wci�� b�dzie w pobli�u. //
END

A teraz pozosta�e bloki.

IF ~~ THEN BEGIN Greet
SAY ~A wi�c potrzebujesz w dru�ynie paladyna?~
IF ~~ THEN REPLY ~Ze wzgl�du na nasz fach, owszem.~ DO ~SetGlobal("VondoPrzylaczony","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, odejd�.~ GOTO Odejscie
END

IF ~~ THEN BEGIN BothPaladins
SAY ~Inny paladyn! Witaj przyjacielu. Pozw�l mi podr�owa� razem i niszczy� z�o.~
IF ~~ THEN REPLY ~Brzmi nie�le.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, odejd�.~ GOTO Odejscie
END

IF ~~ THEN BEGIN GoAway *
SAY ~Dobrze, poczekam do dnia kiedy powr�cisz, i kiedy b�dziemy mogli uderzy� na z�o!~
IF ~~ THEN EXIT
END

* Blok "GoAway" demonstruje sytuacje, w kt�rej gracz po prostu przyciska enter by kontynuowa� dialog. W tym przypadku nast�puje zako�czenie rozmowy.
Tak wi�c mamy ju� wszystko czego nam potrzeba dla stanu, w kt�rym gracz i Vondo spotkali si� po raz pierwszy. Teraz musimy stworzy� dialog dla gracza powracaj�cego do rozmowy z NPC'em.

IF ~NumTimesTalkedToGT(0)~ THEN BEGIN ReturnDialogue
SAY ~Widz�, przyjacielu, �e zdecydowa�e� si� powr�ci�.~
IF ~~ THEN REPLY ~Ano, przy��cz si� do mojej dru�yny.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Tak, jednak wci�� nie chc� ci� w dru�ynie.~ GOTO RefusedAgain
END

IF ~~ THEN BEGIN RefusedAgain
SAY ~Ach, zn�w odm�wi�e�. Nie wa�ne, zajm� si� magicznym urz�dzeniem, jakie naby�em od pewnego gnoma, kt�ry si� zwa� chyba... John? John Johnson? Czy jako� tak...~
IF ~~ THEN EXIT
END

I mamy ju� wst�pny dialog NPCa. Nast�pnym, absolutnie koniecznym plikiem jest *P.dlg czyli plik dialogowy odpalany, kiedy chcesz wyrzuci� swojego NPCa z dru�yny.
O co mi chodzi: Vondo przy��cza si� do dru�yny (korzystaj�c z J#Vondo.dlg), i automatycznie przydzielane mu s� trzy dialogi poprzez r�ne pliki zasad .2da (Pdialog.2da i Interdia.2da). Kiedy wyrzucasz go z dru�yny, uruchamia si� *P.dlg i sprawdza pierwszy stan kt�ry jest prawdziwy.
Jako�e zaczynamy nowy plik .dlg, potrzebny jest nam wers...

BEGIN J#VondoP

Teraz, J#VondoP zostanie dodane do pdialog.2da . Nawi�zuj�c do obecnej tre�ci naszego pliku .dlg, kod b�dzie wygl�da� tak:

IF ~Global("VondoJoined","LOCALS",1)~ THEN BEGIN KickOut // Jest to zmienna jaka zosta�a ustalona kiedy Vondo przy��cza� si� do dru�yny. Je�eli ma ona warto�� 1, oznacza to, �e Vondo jest obecnie w dru�ynie, i dzi�ki temu zostaje wyrzucony kiedy *P.dlg zostaje uruchomione. //
SAY ~A wi�c mnie wyrzucasz.~
IF ~~ THEN REPLY ~Ups, chcia�em wywali� t� �ajz� Anomena, nie ciebie. Przepraszam.~ DO ~JoinParty()~ EXIT // P.dlg automatycznie wyrzuca NPCa przez co je�li chcemy go rzeczywi�cie zostawi�, musimy ponownie u�y� komendy JoinParty().//
IF ~~ THEN REPLY ~Dok�adnie, nie chc� ci� w dru�ynie.~ DO ~SetGlobal("VondoJoined","LOCALS",0)~ EXIT // Zmienna "VondoJoined" zostaje ustalona na poziomie 0, co oznacza, �e zosta� wyrzucony. //
END

A wi�c ca�y blok wygl�da� powinien tak.

IF ~Global("VondoJoined","LOCALS",1)~ THEN BEGIN KickOut
SAY ~A wi�c mnie wyrzucasz.~
IF ~~ THEN REPLY ~Ups, chcia�em wywali� t� �ajz� Anomena, nie ciebie. Przepraszam.~ DO ~JoinParty()~ EXIT
IF ~~ THEN REPLY ~Dok�adnie, nie chc� ci� w dru�ynie.~ DO ~SetGlobal("VondoJoined","LOCALS",0)~ EXIT
END

I to wszystko czego potrzebujesz by go wykopa�. I teraz, by m�c go zn�w przy��czy�, nale�y napisa�:

IF ~Global("VondoJoined","LOCALS",0)~ THEN BEGIN Rejoin
SAY ~Chcesz, bym powr�ci�?~
IF ~~ THEN REPLY ~Tak Vondo, wracaj do szyku.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, nadal cie nie chc�.~ EXIT
END

I to w sumie wszystkie dialogi potrzebne dla NPCa. Reszta to ju� tylko dodatki. Fina�owa wersja twojego pliku .d powinna wygl�da� tak...

BEGIN J#Vondo
IF ~NumTimesTalkedTo(0)~ FirstMeeting
SAY ~Witaj dobry ! Na imi� mi Vondo Sprawiedliwy.~
IF ~GlobalLT("Chapter","GLOBAL",3)~ THEN REPLY ~Hej Vondo, nie widzia�e� gdzie� tutaj czasem Irenicusa?~ GOTO InquireIrenicus
IF ~~ THEN REPLY ~Heja.~ GOTO Greet
+ ~Class(Player1,PALADIN)~ + ~Kiedy widz� paladyna, bez problemu go rozpoznaj�!~ + BothPaladins
++ ~Odejd�.~ + GoAway
END

IF ~~ THEN BEGIN Greet
SAY ~A wi�c potrzebujesz w dru�ynie paladyna?~
IF ~~ THEN REPLY ~Ze wzgl�du na nasz fach, owszem.~ DO ~SetGlobal("VondoPrzylaczony","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, odejd�.~ GOTO Odejscie
END

IF ~~ THEN BEGIN BothPaladins
SAY ~Inny paladyn! Witaj przyjacielu. Pozw�l mi podr�owa� razem i niszczy� z�o.~
IF ~~ THEN REPLY ~Brzmi nie�le.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, odejd�.~ GOTO Odejscie
END

IF ~~ THEN BEGIN GoAway
SAY ~Dobrze, poczekam do dnia kiedy powr�cisz, i kiedy b�dziemy mogli uderzy� na z�o!~
IF ~~ THEN EXIT
END

IF ~NumTimesTalkedToGT(0)~ THEN BEGIN ReturnDialogue
SAY ~Widz�, przyjacielu, �e zdecydowa�e� si� powr�ci�.~
IF ~~ THEN REPLY ~Ano, przy��cz si� do mojej dru�yny.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Tak, jednak wci�� nie chc� ci� w dru�ynie.~ GOTO RefusedAgain
END

IF ~~ THEN BEGIN RefusedAgain
SAY ~Ach, zn�w odm�wi�e�. Nie wa�ne, zajm� si� magicznym urz�dzeniem, jakie naby�em od pewnego gnoma, kt�ry si� zwa� chyba... John? John Johnson? Czy jako� tak...~
IF ~~ THEN EXIT
END

BEGIN J#VondoP
IF ~Global("VondoJoined","LOCALS",1)~ THEN BEGIN KickOut
SAY ~A wi�c mnie wyrzucasz.~
IF ~~ THEN REPLY ~Ups, chcia�em wywali� t� �ajz� Anomena, nie ciebie. Przepraszam.~ DO ~JoinParty()~ EXIT
IF ~~ THEN REPLY ~Dok�adnie, nie chc� ci� w dru�ynie.~ DO ~SetGlobal("VondoJoined","LOCALS",0)~ EXIT
END

IF ~Global("VondoJoined","LOCALS",0)~ THEN BEGIN Rejoin
SAY ~Chcesz, bym powr�ci�?~
IF ~~ THEN REPLY ~Tak Vondo, wracaj do szyku.~ DO ~SetGlobal("VondoJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Nie, nadal cie nie chc�.~ EXIT
END

Na pierwszy rzut oka wygl�da dosy� trudno, jednak �atwo si� do tego mo�na przyzwyczai�.
Gratulacje, w�a�nie sko�czy�e� czyta� Cz�� I! Reszta jest o wiele kr�tsza, wi�c nie ma co si� martwi�.

2. Tworzenie .CRE.
To dosy� �atwa i przyjemna cz��. Po prostu zacznij sesj� multiplayer (nie musisz mie� dost�pu do internetu, wystarczy, �e stworzysz gr� w sieci LAN z jednym graczem) i stw�rz posta�. Daj mu co chcesz, do�wiadczenie, ekwipunek, statystyki i go wyeksportuj.
Zr�b ostatnie zmiany w jego pliku .CHR za pomoc� Shadow Keepera, DLTCEP lub NearInfinity a p�niej otw�rz plik w tym ostatnim. Przewi� na d� do cz�ci "Characters", znajd� swoj� now� posta� i j� otw�rz. W menu File wybierz "Convert CHR to CRE".

Kiedy plik ju� jest w formacie .CRE , mo�esz mu nada� jego Death Variable (Zmienna �mierci), pliki dialogowe, skrypty i oznaczenia.
Teraz, by zmieni� Death Variable (teraz lepiej znan� jako Nazwa Skryptowa - wybaczcie, jestem staro�wiecki), powiniene� poszuka� warto�ci 0x2e4. A po ludzki, oznacza to gdzie� 2/3 drogi w d� pliku, przynajmniej w NearInfinity. Tak wi�c b�dzie to oznaczenie twojego NPCa w grze. Dla przyk�adu s� takie Death Variables jak "Minsc", "Jaheira" czy "Imoen2". Proponuj� u�ywa� swojego unikalnego prefiksu w tym polu. Tak wi�c ustalimy DV Vonda jako "j#vondothejust".
Pole to mo�e mie� tak� sam� nazw� jak tw�j plik CRE, jednak nie musi. By wykaza� to na przyk�adzie, ustalili�my DV jako j#vondothejust, tak wi�c r�nica pomi�dzy nazw� pliku a nazw� skryptow� jest widoczna.

Obecnie skrypty s� niewa�ne, jednak ju� teraz lepiej by by�o, by� oznaczy� pole override script jako "J#Vondo". To oznacza, i� kiedy stworzysz skrypt J#Vondo.bcs, zostanie on przyporz�dkowany do tego pliku .CRE. Powiniene� te� wyczy�ci� resztki po twoim pliku .CHRE (gdzie pewnie znajduj� si� dplayer3.bcs), i zostawi� w nich pustk�. Jednak je�li chcesz by tw�j NPC zaczyna� dialog kiedy zobaczy gracza, u�yj shoudl2.bcs. Je�li chcesz, by podszed� do gracza i zacz�� rozmow�, u�yj initdlg.bcs. Jako podstawowy skrypt walki mo�esz u�y� WTASIGHT.bcs lub WTARSGT.bcs dla broni dystansowej. Tak wi�c powiniene� mie� J#Vondo przyporz�dkowane dla override, initdlg.bcs poni�ej i wtasight lub wtarsght.bcs jeszcze ni�ej.

Przyporz�dkowanie dialogu to warto�� 0x330, w tym samym miejscu co Nazwa Skryptowa/Death Variable tylko troszk� ni�ej. U�yj P-klikni�cia na polu, wybierz "Edit as string" i wpisz jako J#Vondo. To oznacza, �e kiedy nasz sko�czony produkt b�dzie zainstalowany, za� dialogi skompilowane, J#Vondo.cre b�dzie od razu u�ywa� J#Vondo.dlg.

Na koniec, ma�a zmiana o kt�rej wi�kszo�� zapomina, i mo�e ona by� przyczyn� wieelu kl�tw i kurw�w-wasz�w-maci�w rzucanych do nieba. Przewi� na g�r� swojego pliku .cre i znajd� Flags field (Oznaczenia). W �wie�o skonwertowanym pliku .cre, oznaczenie "Export allowed" (mo�liwy eksport) jest wci�� oznaczona. Odznacz. Mog�a ona powodowa� r�ne niemi�e efekty w skryptach i dialogach, mog�cych by� zast�pione przez te dla multi-playera. A nie chcieliby�my chyba tego.

No i to wszystko je�li chodzi o pliki .CRE.

3. Skrypty.
Ten krok jest ju� w sumie prawie ca�y wykonany poprzez dodanie do naszego pliku .cre initdlg.bcs.

IF
See([PC])
NumTimesTalkedTo(0)
THEN
RESPONSE #100
Dialogue(Nearest([PC]))
END

Jednak mo�emy u�y� skrypt�w do wprowadzenia twojego NPCa do �wiata gry, poprzez dodanie kilku linijek do istniej�cego skryptu obszaru. Powiedzmy, �e chcemy go doda� do Dzielnicy Rz�dowej. Musimy wi�c nadpisa� troch� plik AR1000.bcs. Tak wi�c stw�rzmy skrypt zwany AR1000.baf kt�ry b�dzie zawiera� to co chcemy doda�.

IF
Global("J#VondoExists","AR1000",0)
THEN
RESPONSE #100
SetGlobal("J#VondoExists","AR1000",1)
CreateCreature("J#Vondo",[1137.2046],3) // 1137.2046 to koordynaty x.y warunkuj�ce gdzie si� pojawi. 3 to kierunek w jaki jest odwr�cony. Mo�e on wynosi� od 0 (po�udnie) do 15 id�c z ruchem wskaz�wek zegara.
END

Ta cz�� skryptu zostanie dodana przez nasz instalator, i b�dzie nadpisana do AR1000.bcs przez WeiDU kiedy b�dzie trzeba. Przeczytaj ostatni� cz��, by wiedzie� jak to zrobi�.

4. Plik TP2 dla WeiDU.
Plik .tp2 jest kodem instalacyjnym, kt�ry zainstaluje twojego NPCa na innym komputerze poprzez kompilacj� dialog�w, skrypt�w i dodaj�c tekst do ich dialog.tlk oraz przyporz�dkowaniu nowego tekstu do odpowiednich rzeczy.
ZR�B:
1) Otw�rz g��wny folder BG2
2) Stw�rz folder o nazwie VondoNPC
3) Otw�rz ten folder i w �rodku stw�rz folder zwany Backup
4) Skopiuj swoje pliki .CRE, .BAF i .D do folderu VondoNPC
5) Wr�c do g��wnego folderu BG2
6) Skopiuj/wklej tam plik WeiDU.exe i nazwij go VondoNPC-setup.exe
7) W g��wnym folderze BG2 stw�rz plik tekstowy zwany VondoNPC-setup.tp2
OTW�RZ plik tp2 za pomoc� swojego procesora/edytora tekstu i nadal czytaj tutorial by wiedzie� co powinno si� tam znale��.

BACKUP ~VondoNPC\backup~
AUTHOR ~ghreyfain@pocketplane.net~
BEGIN ~Vondo NPC dla BG2:TB~ // Tutaj masz kopiowanie pliku .CRE Vonda oraz nadawanie mu zestawu d�wi�kowego. Sprawd� plik sndslot.ids by ods�ucha� d�wi�ki jakie mo�esz doda�. //
COPY ~VondoNPC\J#Vondo.cre~ ~override\J#Vondo.cre~
SAY NAME1 ~Vondo~
SAY NAME2 ~Vondo~
SAY SELECT_COMMON4 ~Blablabla.~ [Vondo1] // [Vondo1] to nazwa pliku .wav z tym d�wi�kiem //
SAY SELECT_COMMON5 ~Daj mi rozkaz.~ [Vondo2]
SAY SELECT_COMMON6 ~Prosto do celu.~ [Vondo3]
SAY SELECT_ACTION1 ~Jestem w pracy.~ [Vondo4]
SAY SELECT_ACTION2 ~Jak sobie �yczysz.~ [Vondo5]

// Nast�pny wers nakazuje WeiDU skompilowa� plik .d //

COMPILE ~VondoNPC\J#Vondo.d~
COMPILE ~VondoNPC\J#Vondo.baf~ // Ten za� kompiluje skrypt i wrzuca go do override. Nie mamy jednak obecnie w�asnego skryptu, wi�c ta linijka nie jest potrzebna. //
EXTEND_TOP ~Ar1000.bcs~ ~VondoNPC\ar1000.baf~// Z kolei tutaj mamy nadpisanie skryptu AR1000.bcs tym co zapisali�my w pliku AR1000.baf //

Po tym, poprzez nast�puj�ce komendy w .tp2, wprowadzamy dla Vonda kilka linijek do plik�w .2DA (plik zasad).

Powinienem troch� rozja�ni� co wog�le ten kod oznacza. A wi�c, plik pdialog.2da to tabela kt�ra do��cza do NPCa poszczeg�lne skrypty i dialogi.
Pierwszy wyraz to nazwa skryptowa (Death Variable) naszej postaci, w tym przypadku j#vondothejust.

Nast�pny to plik dialogowy w kt�rym zawarte jest wyrzucenie postaci z dru�yny.

"J" oznacza plik jako interakcje i dialogi odbywaj�ce si� gdy posta� znajduje si� w dru�ynie, takie chocia�by jak flirty czy rozmowy zainicjowane przez gracza.
J#VondoD to plik skrypt�w snu. Dzia�a jak normaln skrypt, lecz bazowo dodaje do ka�dej akcji warunek "gracz w�a�nie wcisn�� przycisk Odpoczynku" do ka�dego bloku warunkowego.

Kolejne cztery pola to po prostu odpowiedniki dialog�w dla Tronu Bhaala. Zalecane jest dodanie ich nawet je�eli posta� nie posiada �adnych dialog�w dla dodatku - nie zaszkodzi.

Komenda UNLESS dla WeiDU m�wi programowi by nadpisywa� tekst je�li J#Vondothejust nie zosta�o ju� wcze�niej wpisane do pliku.

APPEND ~pdialog.2da~
~J#VondoTheJust J#VondoP J#VondoJ J#VondoD J#Von25P J#Von25J J#Von25D J#Vond25~
UNLESS ~J#VondoTheJust~

Interdia.2da jest troch� �atwiejszy, jednak dzia�a na takiej samej zasadzie co pdialog.2da. Dodaje postaci pliki banter�w, kt�re wykorzystywane s� w rozmowach mi�dzy postaciami i romansach.

APPEND ~interdia.2da~
~J#VondoTheJust J#VondoB J#VonB25~
UNLESS ~J#VondoTheJust~

I to wszystko. Mam nadziej�, �e w miar� jasno to wyt�umaczy�em.

zanotowane.pl

doc.pisz.pl

pdf.pisz.pl

funlifepok.htw.pl

Podstrony

Template provided by Designs by Darren Opracowanie Marketing w Internecie dla Seungri â strony, Obrazki i wiele więcej na WordPress